黑馬買賣主圖指標公式

A. 通達信跟庄買賣 主圖指標

把M1,M2,M3，m4等參數設置好

B. 請把主圖買賣點公式改為選股公式謝謝

VAR10:=IF(TROUGHBARS(3,16,1)=0 AND HIGH>LOW+0.04,4,0);
買1:=VAR10;
VAR11:=ZIG(3,6)>REF(ZIG(3,6),1) AND REF(ZIG(3,6),1)<=REF(ZIG(3,6),2) AND REF(ZIG(3,6),2)<=REF(ZIG(3,6),3);
VAR13:=ZIG(3,22)>REF(ZIG(3,22),1) AND REF(ZIG(3,22),1)<=REF(ZIG(3,22),2) AND REF(ZIG(3,22),2)<=REF(ZIG(3,22),3);
VAR15:=ZIG(3,51)>REF(ZIG(3,51),1) AND REF(ZIG(3,51),1)<=REF(ZIG(3,51),2) AND REF(ZIG(3,51),2)<=REF(ZIG(3,51),3);VAR16:=ZIG(3,51)<REF(ZIG(3,51),1) AND REF(ZIG(3,51),1)>=REF(ZIG(3,51),2) AND REF(ZIG(3,51),2)>=REF(ZIG(3,51),3);
VAR17:=ZIG(3,72)>REF(ZIG(3,72),1) AND REF(ZIG(3,72),1)<=REF(ZIG(3,72),2) AND REF(ZIG(3,72),2)<=REF(ZIG(3,72),3);
買2:=(VAR11+VAR13+VAR15+VAR17);
XG:買1>0 OR 買2>0;

溫馨提示:由於公式中使用了未來函數請慎用。 只能在副圖上欣賞，否則是選不出個股。

C. 主圖出現「黑馬」字樣預警公式

多空線:=SMA((O+CLOSE+HIGH+LOW)/4,3,1);
強命線:=EMA(COST(81),10);
CTX:=(3*C+H+L+O)/6;
IONG:=(8*CTX+7*REF(CTX,1)+6*REF(CTX,2)+5*REF(CTX,3)+4*REF(CTX,4)+3*REF(CTX,5)+2*REF(CTX,6)+REF(CTX,8))/36;
CTXIONG:=VOL=HHV(VOL,10) AND VOL>2*REF(VOL,1) AND CLOSE>IONG AND C>O;
XG:=FILTER(CTXIONG,5);
BB1:=CROSS(多空線,強命線);
VBR1:=EMA(CLOSE,8);
VBR2:=EMA(CLOSE,20);
YA:=IF(C>=O,AMOUNT,0);
YAOBV:=SUM(YA,0);
MOBV:=SUM(AMOUNT,0);
BL:=100*YAOBV/MOBV;
MABL3:=IF(BARSSINCE(C)>=3,MA(BL,3),50);
MABL30:=IF(BARSSINCE(C)>=30,MA(BL,30),MABL3);
SSS3:=COUNT(CROSS(VBR1,VBR2),10)>=1;
SSS4:=COUNT(CROSS(MABL3,MABL30),10)=1;
SC:COUNT(XG,5)>=1 AND BB1 AND SSS3 AND SSS4;

D. 通達信最佳買賣點主圖指標公式轉換成選股公式

{未來函數，慎用}
買:CROSS(ZIG(3,10) ,REF(ZIG(3 ,10),1));

E. 麻煩大神幫我把這個主圖指標改成通達信選股公示，特別是暴漲黑馬那個，謝謝！

特別提示:該指標使用了XMA未來函數，

官方給出的說明，」只供內部測試使用「；

另外，使用該指標選股，目前沒有符合條件的個股出現，

可以設置為---

時間段內滿足條件（2018-02-14~2018-02-14），可以選取一隻個股。

ZK1:=(XMA(XMA(H,25),25)-XMA(XMA(L,25),25))*1+XMA(XMA(H,25),25);
ZD1:=XMA(XMA(L,25),25)-(XMA(XMA(H,25),25)-XMA(XMA(L,25),25))*1;
DY:=CURRBARSCOUNT=1 AND C<REF(C,1);
JJ:=(HIGH+LOW+CLOSE)/3;
QJ0:=VOL/IF(HIGH=LOW,4,HIGH-LOW);
QJ1:=IF(CAPITAL=0,QJ0*(JJ-MIN(CLOSE,OPEN)),QJ0*IF(HIGH=LOW,1,(MIN(OPEN,CLOSE)-LOW)));
QJ2:=IF(CAPITAL=0,QJ0*(MIN(OPEN,CLOSE)-LOW),QJ0*IF(HIGH=LOW,1,(JJ-MIN(CLOSE,OPEN))));
QJ3:=IF(CAPITAL=0,QJ0*(HIGH-MAX(OPEN,CLOSE)),QJ0*IF(HIGH=LOW,1,(HIGH-MAX(OPEN,CLOSE))));
QJ4:=IF(CAPITAL=0,QJ0*(MAX(CLOSE,OPEN)-JJ),QJ0*IF(HIGH=LOW,1,(MAX(CLOSE,OPEN)-JJ)));
DDX:=((QJ1+QJ2)-(QJ3+QJ4))/IF(CAPITAL=0,10000,10000);
V2:=SMA(IF(C>=REF(C,1),DDX,-DDX/100),2,1);
DY2:=REF(V2,1)-DY;
XG:C>O AND DY2<0.02 AND MA(C,5)>MA(C,60) AND C/REF(C,1)>=1.02 AND H<ZK1 AND L<ZD1;

F. 指標公式如何改寫成選股條件公式

【一品抄底】，是個副圖指標，既有線性輸出信號，也有買點提示信號，輸出類別眾多，就不是一個單獨的選股指標。如何修改、拆分出自己需要的【底部】選股信號，成為一個單獨的選股指標呢？如果還需要將【深坑】的信號，也單獨設置為選股指標，又該如何修改呢？在此先當做一個問題吧，繼續看了後面（二）、（三）小節的引路，相信你自己來就行了！
{一品抄底----創幻論壇一品茶緣編寫，通用副圖指標}
TYP := (HIGH + LOW + CLOSE)/3;
CCI:=(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14));
A:=REF(C,1);
RSI:=SMA(MAX(C-A,0),6,1)/SMA(ABS(C-A),6,1)*100;
A1:=(C/MA(C,5)-1)*100<-10;
A2:=(C/MA(C,13)-1)*100<-10;
A3:=(C/MA(C,34)-1)*100<-15;
A4:=RSI<18;
A5:=CCI<-120;
A6:=COUNT(ABS(C/REF(C,1)-1)*100>=6,30)>=1;
底部:A1 AND A2 AND A3 AND A4 AND A5 AND A6,COLOR00FFFF,LINETHICK2;
CDSJ:=BARSLAST(底部);
ZF:=(C/REF(C,1)-1)*100;
深坑:IF(BETWEEN(CDSJ,0,5) AND L<=REF(C,CDSJ) AND ZF<=-5,-0.5,0),COLORFF0000,LINETHICK2;
機會:IF(CDSJ<=7 AND L<=REF(C,CDSJ),0.5,0),COLOR00FF00;
尋找選股信號的來源

所謂選股信號，多數都是屬於將已有的指標公式中具有買點類的信號特徵「剝離」出來。那麼，在指標中該保留哪些有用的源碼，刪除哪些無關的源碼呢？尋找選股信號的來源，就是最主要的過程。
尋找選股信號來源的方法，一般都是遵循從後往前尋找的原則。
具體步驟是：先找到發出指標信號的那行代碼，然後查看該行代碼中的所有條件，需要用到上面哪些源碼，再從後往前一一對應尋找出來；而其他無關的條件、修飾符號源碼，均可刪除。
舉例3：（本例子參考大慶老楊先生帖子，略有改動）
{股市馬經----副圖指標，源碼來自網路}
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:EMA(A1,5),LINETHICK2,COLOR6600FF;
A2:=(黑馬線-REF(黑馬線,1))/REF(黑馬線,1)*100;
A3:=EMA(C,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
A5:=(HHV(H,60)-C)/(HHV(H,60)-LLV(L,60))*100;
DRAWTEXT(FILTER(REF(黑馬線,1)>90 AND A2<0,7),黑馬線,'跑'),COLOR00FF00;
DRAWTEXT(CROSS(A1,黑馬線)AND 黑馬線<A5,黑馬線,'黑馬');
DRAWTEXT(CROSS(黑馬線,A5)AND 趨勢線<80,黑馬線,'追漲');
DRAWTEXT(CROSS(趨勢線,0)AND 黑馬線<40,5,'大黑馬');
底部:(A2<-10 AND A2>REF(A2,1))*25,colorred;
DRAWICON(底部 AND A3>REF(A3,1),25,4);
機會來臨:REF(IF((MA(C,5)-C)/C>0.04 AND (MA(C,10)-MA(C,5))/MA(C,5)>0.04,30,0),1),COLORF00FF0;
大勢已去:IF(CROSS(黑馬線,A1)AND 黑馬線>70 AND 趨勢線>80,90,100),COLORFF0000;
公式中涉及「買」的信號有黑馬、追漲、大黑馬、底部和機會來臨五個明顯的，另外還有一個畫圖標信號。

假如我們提取其中的【機會來臨】，仔細分析後，就是一句話：
機會來臨:REF(IF((MA(C,5)-C)/C>0.04 AND (MA(C,10)-MA(C,5))/MA(C,5)>0.04,30,0),1);
這個可看作簡單提取。

如果提取【大黑馬】的話，從後向前推，涉及趨勢線和黑馬線兩個定義，這部分都有用：
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:EMA(A1,5),LINETHICK2,COLOR6600FF;
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
DRAWTEXT(CROSS(趨勢線,0) AND 黑馬線<40,5,'大黑馬');

（三）修改選股指標的方法

根據以上選股公式的特徵，結合尋找選股信號來源的方法，自己動手修改選股信號，應該就沒有太大的難度了！

舉例4：繼續承接上面（二）的例子。
修改步驟：
①先將線性輸出的A1、黑馬線、A4、趨勢線均限制輸出，方法很簡單，就是在他們的冒號後面直接加上等號=；
②再刪去修飾符LINETHICK2,COLOR6600FF：
③將本來是文字輸出的「黑馬線」修改成信號輸出；先將「黑馬線」三個字移動到最前面，並加上冒號：；然後保留符合黑馬線的限制條件CROSS(趨勢線,0) AND 黑馬線<40；同時刪除其餘無關的代碼，包括文字輸出函數DRAWTEXT、位置、括弧（）等。
修改成選股指標後的源碼如下：
A1:=3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:=EMA(A1,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:=(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2));
大黑馬:CROSS(趨勢線,0) AND 黑馬線<40;

舉例5：
下面附圖指標【大三浪】中，如何選出出現「買」字提示信號的選股指標？
{大三浪----創幻論壇一品茶緣編寫，通用副圖指標}
{大三浪指標使用說明:
均線粘合且多頭,長期未漲庄吸籌;
目標鎖定先跟蹤,出擊買入等豐收!}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
多頭粘合:IF(多頭 AND 粘合,1,0),COLORFF00FF,POINTDOT,LINETHICK0;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目標:IF(多頭 AND 粘合 AND 庄股,5,0),COLORFFFFFF,LINETHICK2;
跟蹤:IF(目標,BARSLAST(CROSS(目標,0))+1,0),COLOR00FF00,POINTDOT,LINETHICK2;
出擊:IF(CROSS(0.1,目標) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
MJSJ:=BARSLAST(出擊>0);
漲幅:IF(MJSJ<=120,(C/REF(C,MJSJ)-1)*100,0),COLOR0000FF,POINTDOT,LINETHICK0;
日漲:IF(MJSJ<=120,漲幅/MJSJ,0),COLORFFFFFF,POINTDOT,LINETHICK0;
TPX:=MIN(MA65*1.15,MA21*1.13);
突破:IF(CROSS(C,TPX) AND 粘合 AND MA65>REF(MA65,1),10,0),COLOR0000FF,LINETHICK2;
{以下設置副圖顯示方式}
STICKLINE(多頭粘合,0,1,8,0),COLORFF00FF;
STICKLINE(庄股,0,MACD*10,8,0),COLORFFFF00;
DRAWTEXT(出擊=8,10,'★買'),COLOR00FFFF;
VERTLINE(CROSS(漲幅,20) AND COUNT(CROSS(漲幅,20),MJSJ)=1,2),COLOR0000FF; 根據選股指標的步驟，一步一步來：
①首先找到出現「★買」提示的一行代碼，發現她其實就是「出擊」的信號；
②從後往前，找到「出擊」信號的條件，發現他與「目標」、MACD有關；
再次往前尋找，又發現「目標」信號的條件，與「多頭」、「粘合」、「庄股」三個條件有關，由此，保留相關條件代碼，其餘刪除，如下：
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目標:IF(多頭 AND 粘合 AND 庄股,5,0),COLORFFFFFF,LINETHICK2;
出擊:IF(CROSS(0.1,目標) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
③限制輸出數量，只保留「出擊」信號的輸出，其他的輸出信號均加上等號=加以限制輸出；
④刪除多餘的修飾符號，如：COLORFFFF00,POINTDOT,LINETHICK0等。
⑤IF格式也可簡化，只保留需要的條件，輸出信號自動為1。「出擊」兩字也可修改為「買」。
修改完最後保留的源碼如下：
{大三浪----選股指標}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:=COUNT(MACD<0,10)=10;
目標:=IF(多頭 AND 粘合 AND 庄股,5,0);
買:CROSS(0.1,目標) AND CROSS(MACD,0); 導入選股指標的途徑
①修改完後的選股指標源碼，想做成選股指標，並非放在指標系統之下的【技術指標】分類，一般是放入【條件選股】分類；便於設置預警、自動選股。
②還可將選股指標加入交易系統中，但需要注意的是：輸出信號必須為英文單詞的買入ENTERLONG、賣出EXITLONG信號。在應用時，飛狐軟體輸入該交易系統指標名稱，即可在主圖自動顯示買賣信號的提示。
源碼如下：
ENTERLONG:CROSS(MA(C,3),MA(C,8));----表示輸出多頭買入信號。
EXITLONG:CROSS(MA(C,8),MA(C,3));----表示輸出空頭賣出信號。

G. 尋找未來大黑馬通達信指標公式源碼

有好多大黑馬的通達信指標公式源碼，但是不知道你需要的信號是怎麼樣的，圖形那些，所以你可以自行去挑選適合自己的哈！