1. 大智慧ddx選股公式
C<OPEN AND (ddx>0.015);
不過ddx是大智慧的加密指標 無法引入或是本人能力有限
C<OPEN;可以這樣選出收陰的股票 然後用ddx排序。
補充：呵呵。我測試了一下按照樓主的要求會出現上漲的股票，因為會有高開低走的股票，但如果高開太多股價仍然是上漲的！所以補充平開或低開的
REF(C,1)>=OPEN and c<o;
2. 老師可以幫忙編寫個大智慧的10天內多次出現低開高走的選股公式嗎
COUNT(O<REF(C,1) AND C>O,10)>=3;
3. 誰有大智慧的（自動解盤）指標
ma5:ma(c,5);
ma13:ma(c,13);
ma21:ma(c,21);
ma34:ma(c,34);
ma55:ma(c,55);
ma89:ma(c,89);
天高雲淡:=COUNT(ma(C,3)>ref(ma(C,3),1),3)>=3 and C<=ma(C,34) and C>O and C>ref(C,1);
螞蟻撼樹:=COUNT(ref(O,1)>REF(H,2) and ref(C,1)<ref(O,1) and ref(C,1)>ref(C,2),2)>=2;
九天射日:=O>ref(H,1) and (h-max(o,c))/max(o,c)*100>3 and C>L;
彈劍長嘯:=O>ref(H,1) and (h-max(o,c))/max(o,c)*100>3;
兩陽夾一陰:=REF(C,2)>REF(O,2)*1.03{確定前天陽線實體大小} AND REF(C,1)<REF(O,1)*1.005 and ref(c,1)<ref(c,2){確定昨天為陰線收盤價低於前天收盤價} AND C>O*1.023 AND C>REF(C,1)*0.99{確定今天陽線實體收盤價大於昨天陰線};
陽包陰:=ref(c,1)<ref(o,1) and ( ref(o,1) -ref(c,1))/ref(c,2)>0.02{確定昨天陰線實體大小} and o<=ref(c,1) and c>ref(o,1){確定今天陽線將昨天陰線全部吞沒};
包孕線:=ref(c,1)<ref(o,1) and ref((o-c),1)/ref(c,2)>=0.03{確定昨天陰線實體大小} and l>ref(l,1) and c>o and h<ref(o,1){確定今天陽線在昨天陰線實體內};
黎明之星:=ref(c,2)<ref(o,2) and ( ref(o,2) -ref(c,2))/ref(c,3)>=0.03{前天陰線實體大於-3%} and abs(ref(c,1)-ref(o,1))<( ref(o,2) -ref(c,2))/3 and (ref(h,1)<( ref(o,2) -ref(c,2))/3+ref(c,2)) and abs(ref(c,2)-ref(c,1))/ref(c,3)<=0.01{昨天跌幅小於1%的小陰或小陽，小陰的開盤價，小陽的收盤價要在前天的收盤價附近} and c>ref(c,1)*1.03 and c>( ref(o,2) -ref(c,2))/3*2+ref(c,2){今天大與3%，實體進入前天的陰線實體的三分之一以上};
直上青雲:=COUNT(C>REF(C,1),3)>=3 and O>ref(H,1) and C=O;
背水一戰:=o<ref(o,1) and c>o and 100*(c/ref(c,1)-1)>3 and c>ref(o,1) and ref(c,1)<ref(o,1) and (ref(o,1)<ref(c,2) or ref(o,1)>ref(c,2)) and ref(c,2)>ref(o,2) and ref(100*(c/ref(c,1)-1),2)>3;
趁熱打鐵:=COUNT(V>REF(V,1),3)=3 AND COUNT(C>O AND (C-O)>REF(C,1)-REF(O,1),3)=3 AND 100*(REF(C,2)/REF(C,3)-1)>2;
芝麻開花:=ref(O,1)>ref(H,2) and ref(C,1)>ref(O,1) and O>ref(H,1) and l>=O and C>O and (C/ref(C,1)-1)*100>4;
早晨之星:=REF(CLOSE,2)/REF(OPEN,2) < 0.95 AND REF(OPEN,1) < REF(CLOSE,2) AND ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.03 AND
CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2);
黃昏之星:=REF(CLOSE,2)/REF(OPEN,2) > 1.03 AND REF(OPEN,1) > REF(CLOSE,2) AND ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.02 AND
CLOSE/OPEN<0.97 AND CLOSE<REF(CLOSE,2);
長十字:=CLOSE=OPEN AND HIGH/LOW >1.03;
垂死十字:=CLOSE=OPEN AND CLOSE=LOW AND CLOSE<>HIGH;
早晨十字星:=REF(CLOSE,2)/REF(OPEN,2) < 0.95 AND REF(OPEN,1) < REF(CLOSE,2) AND REF(OPEN,1)=REF(CLOSE,1) AND
CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2);
黃昏十字星:=REF(CLOSE,2)/REF(OPEN,2) > 1.05 AND REF(OPEN,1) > REF(CLOSE,2) AND REF(OPEN,1)=REF(CLOSE,1) AND
CLOSE/OPEN<0.95 AND CLOSE<REF(CLOSE,2);
射擊之星:=MIN(OPEN,CLOSE)=LOW AND HIGH-LOW > 3*(MAX(OPEN,CLOSE)-LOW) AND CLOSE > MA(CLOSE,5);
倒轉錘頭:=MIN(OPEN,CLOSE)=LOW AND HIGH-LOW > 3*(MAX(OPEN,CLOSE)-LOW) AND CLOSE < MA(CLOSE,5);
錘頭:=HIGH = MAX(OPEN,CLOSE) AND HIGH-LOW > 3*(HIGH-MIN(OPEN,CLOSE)) AND CLOSE < MA(CLOSE,5);
吊頸:=HIGH = MAX(OPEN,CLOSE) AND HIGH-LOW > 3*(HIGH-MIN(OPEN,CLOSE)) AND CLOSE>MA(CLOSE,5);
穿頭破腳:=(REF(CLOSE,1)/REF(OPEN,1)>1.03 AND CLOSE/OPEN<0.96 AND CLOSE<REF(OPEN,1) AND OPEN>REF(CLOSE,1))
OR (REF(CLOSE,1)/REF(OPEN,1)<0.97 AND CLOSE/OPEN>1.04 AND CLOSE>REF(OPEN,1) AND OPEN<REF(CLOSE,1));
烏雲蓋頂:=REF(CLOSE,1)/REF(OPEN,1)>1.03 AND CLOSE/OPEN<0.97 AND OPEN>REF(CLOSE,1) AND CLOSE<REF(CLOSE,1);
曙光初現:=REF(CLOSE,1)/REF(OPEN,1)<0.97 AND CLOSE/OPEN>1.03 AND OPEN<REF(CLOSE,1) AND CLOSE>REF(CLOSE,1);
身懷六甲:=ABS(REF(CLOSE,1)-REF(OPEN,1))/REF(CLOSE,1) > 0.04 AND ABS(CLOSE-OPEN)/CLOSE<0.005 AND
MAX(CLOSE,OPEN) < MAX(REF(CLOSE,1),REF(OPEN,1)) AND MIN(CLOSE,OPEN) > MIN(REF(CLOSE,1),REF(OPEN,1));
十字胎:=ABS(REF(CLOSE,1)-REF(OPEN,1))/REF(CLOSE,1) > 0.04 AND CLOSE=OPEN AND
CLOSE < MAX(REF(CLOSE,1),REF(OPEN,1)) AND CLOSE > MIN(REF(CLOSE,1),REF(OPEN,1));
平頂:=ABS(HIGH-REF(HIGH,1))/HIGH<0.001;
平底:=(ABS(LOW-REF(LOW,1))/LOW<0.001 and abs(ref(low,1)-ref(low,2))/ref(low,1)<=0.001);
大陽燭:=CLOSE/OPEN>1.05 AND HIGH/LOW < CLOSE/OPEN+0.018;
三個白武士:=REF(CLOSE,2)>REF(OPEN,2) AND REF(CLOSE,1)>REF(OPEN,1) AND CLOSE>OPEN
AND REF(CLOSE,1)>REF(CLOSE,2) AND CLOSE>REF(CLOSE,1);
雙飛烏鴉:=REF(CLOSE,1)<REF(OPEN,1) AND CLOSE<OPEN AND CLOSE/OPEN<0.98;
孕育線:=REF(CLOSE,2)>REF(OPEN,2) AND (REF(CLOSE,2)-REF(OPEN,2))/REF(OPEN,2)>=2/100 AND REF(OPEN,1)>=REF(CLOSE,1) AND
(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<=2/100 AND REF(OPEN,1)<=REF(CLOSE,2) AND REF(CLOSE,1)>=REF(OPEN,2) AND C>=OPEN AND
(CLOSE-OPEN)/OPEN>=2/100 AND CLOSE>=REF(OPEN,1) AND OPEN<=REF(CLOSE,1) AND (MAX(CLOSE,REF(C,2))-MIN(CLOSE,REF(CLOSE,2)))/MIN(CLOSE,REF(CLOSE,2))<=1/100;
多方炮:=REF(CLOSE,2)>REF(OPEN,2) AND REF(CLOSE,1)<REF(OPEN,1) AND CLOSE>OPEN;
出水芙蓉:=CLOSE>OPEN AND LOW<MA(CLOSE,20) AND LOW<MA(CLOSE,40) AND LOW<MA(CLOSE,30) AND LOW<MA(CLOSE,60) AND CLOSE>MA(CLOSE,30) AND CLOSE>MA(CLOSE,20) AND CLOSE>MA(CLOSE,40) AND CLOSE>MA(CLOSE,60) AND CLOSE>MA(CLOSE,5) AND C=HHV(C,20) AND REF(HHV(H,10),1)/REF(LLV(H,10),1)<1.05 AND (CLOSE-OPEN)>0.02*CLOSE;
上升三部曲:=REF(CLOSE,4)/REF(OPEN,4)>1.03 AND REF(CLOSE,3)<REF(OPEN,3) AND REF(CLOSE,2)<REF(OPEN,2) AND REF(CLOSE,1)<REF(OPEN,1) AND
REF(LOW,4)<REF(LOW,3) AND REF(LOW,4)<REF(LOW,2) AND REF(LOW,4)<REF(LOW,1) AND REF(HIGH,4)>REF(HIGH,3) AND REF(HIGH,4)>REF(HIGH,2) AND
REF(HIGH,4)>REF(HIGH,1) AND CLOSE/OPEN>1.03 AND CLOSE>REF(CLOSE,4);
下跌三部曲:= REF(CLOSE,4)/REF(OPEN,4)<0.97 AND REF(CLOSE,3)>REF(OPEN,3) AND REF(CLOSE,2)>REF(OPEN,2) AND REF(CLOSE,1)>REF(OPEN,1) AND REF(LOW,4)<REF(LOW,3) AND
REF(LOW,4)<REF(LOW,2) AND REF(LOW,4)<REF(LOW,1) AND REF(HIGH,4)>REF(HIGH,3) AND REF(HIGH,4)>REF(HIGH,2) AND REF(HIGH,4)>REF(HIGH,1) AND CLOSE/OPEN<0.97 AND
CLOSE<REF(CLOSE,4);
跳空缺口:=HIGH<REF(LOW,1) OR LOW>REF(HIGH,1);
三隻烏鴉:=REF(CLOSE,2)<REF(OPEN,2) AND REF(CLOSE,1)<REF(OPEN,1) AND CLOSE<OPEN AND REF(CLOSE,1)<REF(CLOSE,2) AND CLOSE<REF(CLOSE,1);
光腳陰線:=LOW=CLOSE AND HIGH<>LOW;
光頭陽線:=HIGH=CLOSE AND HIGH<>LOW;
分離:=OPEN=REF(OPEN,1) AND (CLOSE-OPEN)*(REF(CLOSE,1)-REF(OPEN,1))<0;
長下影:=(MIN(CLOSE,OPEN)-LOW)/(HIGH-LOW)>0.667;
長上影:=(HIGH-MAX(CLOSE,OPEN))/(HIGH-LOW)>0.667;
十字星:=CLOSE=OPEN AND HIGH<>LOW;
大陰燭:=OPEN/CLOSE > 1.05 AND HIGH/LOW < OPEN/CLOSE+0.018;
好友反攻:=(REF(CLOSE,1)<REF(OPEN,1) AND CLOSE>OPEN AND ABS(CLOSE-REF(CLOSE,1))/CLOSE<0.002)
OR (REF(CLOSE,1)>REF(OPEN,1) AND CLOSE<OPEN AND ABS(CLOSE-REF(CLOSE,1))/CLOSE<0.002);
傾盆大雨:=REF(C,1)/REF(O,1)>=1.03 AND O<REF(C,1) AND O>REF(O,1) AND C<REF(O,1);
三重底:=(hhv(c,3)-llv(c,3))/llv(c,3)<0.01;
跳空陰線後星:=ref(o>c,4) and ref(h<ref(l,1) and (ref(c,1)-l)/ref(c,1)>0.07 and (o-c)/ref(c,1)>0.04{最大跌幅大於7％，實體大於4％}
,3) and ref(abs(o-c)<ref((o-c),1)*0.3 and (h-l)>1.8*abs(c-o) and h>=ref(l,1) and (h-l)<ref((h-l),1)*0.75 and l<ref(c,1){星線}
,2) and ref(abs(o-c)<ref((o-c),2)*0.3 and (h-l)>1.8*abs(c-o) and h>=ref(l,1) and (h-l)<ref((h-l),2)*0.75 and l<ref(max(c,o),1){星線}
,1) and l>ref(llv(l,2),1) and l<ref(max(c,o),1) and (h-l)<ref((h-l),3)*0.75{星線};
均粘陽破:=count(max(max(max(max(ma(c,5),ma(c,10)),ma(c,20)),ma(c,30)),ma(c,55))/min(min(min(min(ma(c,5),ma(c,10)),ma(c,20)),ma(c,30)),ma(c,55))<1.05,3)>=1 and o<ma(c,10) and c>max(max(max(max(ma(c,5),ma(c,10)),ma(c,20)),ma(c,30)),ma(c,55)) and c/o>1.03 and min(min(min(min(ma(c,5),ma(c,10)),ma(c,20)),ma(c,30)),ma(c,55))>ma(c,144) and ma(c,144)>ma(c,233) and v>max(max(ma(v,13),ma(v,34)),ma(v,55));
陰線巨量收復:=ref(c<o and v>ref(hhv(v,10),1)*2.5,1) and c>o and v<ref(v,1)/2 and c>ref(h,1) or ref(c<o and v>ref(hhv(v,10),1)*2.5,2) and ref(c,1)<ref(h,2) and c>o and v<ref(v,2)/2 and c>ref(h,2) or ref(c<o and v>ref(hhv(v,10),1)*2.5,3) and ref(hhv(c,2),1)<ref(h,3) and ref(hhv(v,2),1)<ref(v,3) and c>o and v<ref(v,3)/2 and c>ref(h,2) or ref(c<o and v>ref(hhv(v,10),1)*2.5,4) and ref(hhv(c,3),1)<ref(h,4) and ref(hhv(v,3),1)<ref(v,4) and c>o and v<ref(v,4)/2 and c>ref(h,2);
DRAWFLAGTEXT(天高雲淡>0,HIGH,'天高雲淡--上升中途小壓迫線：多方連續發力向上，在收出陽線的次日股價大幅高開，至尾市時收盤價落至開盤價以下，但仍高於前一日收盤價，形成高檔小壓迫線。此種圖形通常表空頭的壓制力量有限，多方將乘虛而入，將股價推上新高。高檔的小壓迫線本身常常意味空頭力量薄弱，故在形成壓迫線當天一般是入貨良機，或者在第二天開市時可以介入。如果壓迫線與前一天的陽線之間留有跳空缺口（即該壓迫線沒有下影線），考慮及早介入。'),COLORRED;
DRAWFLAGTEXT(螞蟻撼樹>0,HIGH,'螞蟻撼樹--上升中途偽陰線：股價上升途中，多頭向空方發起猛烈進攻，導致股價大幅高開，空頭也不甘示弱，盡力將股價向下打壓，連續兩日收出陰線，但兩根陰線的收盤價都高於前一天收盤價，形成偽陰線。本K線組合中連續兩根小陰線都無法遏制多頭的進攻，通常會導致多空力量對比更加不平衡，股價一般將加速上行。故投資者一般可在第二根陰線處考慮加入多方陣營，以便分享勝利成果。 '),COLORRED;
DRAWFLAGTEXT(陰線巨量收復,HIGH,'陰線巨量收復'),COLORCYAN;
DRAWFLAGTEXT(傾盆大雨,HIGH,'傾盆大雨,見頂信號'),COLORCYAN;
DRAWFLAGTEXT(跳空陰線後星,HIGH,'跳空陰線後星'),COLORRED;
DRAWFLAGTEXT(九天射日>0,HIGH,'九天射日--上升中途跳高弓形線：股價上升途中，多方奮力向上，但遭空頭狙擊，不得不回撤至較低價位，從而在K線圖上走出一根長上影K線（即弓形線）。由於K線組合中空頭力量在製造「長弓」過程中已消耗殆盡，因而弓形線形成時即介入良機，即使第二天不能形成將這一弓形線包容在內的大陽，股價上行一般不會改變。如第二天多頭盡全力向上攻擊，將前一日長上影全部抹去，則股價將加速上行，連收陽線。如第二天多頭不能攻上弓形線最高點，而是收出一根包孕在此弓形線長上影之內的中小陽線，就說明多頭上攻遇到較大阻力，雖不能就此妄言股價見頂，但其後上攻速度將放慢.'),COLORRED;
DRAWFLAGTEXT(彈劍長嘯>0,HIGH,'彈劍長嘯--上升中途跳高劍形線：隨著市場氣氛回暖，看好後市的人迅速增多，導致股價以較大缺口向上跳空開盤，其後雖受獲利盤打壓向下回落，尾市仍被拉高至開盤價附近收市，從而收出一根跳空的劍形線。此圖通常表明空頭反抗力量十分薄弱，如第二天仍以高上跳空的形式開盤，股價一般會加速上揚。K線組合中劍形線的長下影說明空頭也曾拚死抵抗，卻根本無法阻止股價上行，這種情況常常導致一些較敏感的空頭反手做多，股價上行速度將會加快，因此投資者一般應在當天收市前及時跟進，至遲應在第二天跳高開盤時趁早殺入，否則可能錯失一波快速上揚行情。 '),COLORRED;
DRAWFLAGTEXT(直上青雲>0,HIGH,'直上青雲--上升中跳高十字星：隨著股價上升，在中大陽線後常會出現或多或少的類十字星。這些類十字星只是上漲途中的暫時整理而已，次日若股價上揚且伴隨的有效放大，一般為介入信號，通常將再出現一波快速上攻行情。本K線組合中類十字星數量多少不定，少則一顆，多則三、四顆，無論星線多少，只要再次放量上攻，即會加速上揚，故投資者一般應在放量時及時介入，坐享順水推舟之樂。 '),COLORRED;
DRAWFLAGTEXT(趁熱打鐵>0,HIGH,'趁熱打鐵--漸大三連陽：股價上升途中，多頭接連向空頭發起進攻，且攻勢一天比一天猛烈。反映在K線圖上，股價連收陽線，而陽線實體也越來越大，這常常是股價將加速上行的先兆。由於本K線組合中連續陽線的實體是由小變大，一般表明多頭攻勢日見順利，將趁熱打鐵，向空方發起總攻。運用本K線組合時應注意，如K線組合中陽線實體比較大，特別是第三、四天的陽線已是中大陽線的話，就說明多頭力量十分強大，即使遭致空頭反撲，也不過是極短時間的調整，反而成為短線追買的良機。'),COLORCYAN;
DRAWFLAGTEXT(背水一戰>0,HIGH,'背水一戰--跳空攀援線：股價跳空高開突破後，連拉兩根順次向上的陽線（攀援線），多頭盡快將防線向前推進到離第一天跳空缺口較遠的地方，這是多方占優的走勢，一般表明空頭基本放棄抵抗，股價將繼續上行。K線組合中跳空缺口往往預示著多頭背水一戰的決心。本K線組合在第二天的走勢比較關鍵，如能在成交量配合下平開（或略微低開）高走，一般可及早介入，持股待漲。'),COLORRED;
DRAWFLAGTEXT(芝麻開花>0,HIGH,'芝麻開花--二次高開陽線：股價跳空而上，形成陽線，第二天再次跳高開盤，且高走高收，此圖形為多方占優走勢，一般預示著空頭的潰敗，股價可能會快速上行，連拉陽線。投資者應認真觀察第二天高開後的走勢，如股價在成交量配合下順勢高走，可順勢介入操作。'),COLORRED;
DRAWFLAGTEXT(均粘陽破,HIGH,'均線粘大陽破'),COLORRED;
DRAWFLAGTEXT(兩陽夾一陰,HIGH,'兩陽夾一陰'),COLORRED;
DRAWFLAGTEXT(陽包陰,HIGH,'陽包陰'),COLORRED;
DRAWFLAGTEXT(包孕線,HIGH,'包孕線'),COLORRED;
DRAWFLAGTEXT(黎明之星,HIGH,'黎明之星'),COLORRED;
DRAWFLAGTEXT(三重底,HIGH,'三重底,發生逆轉'),COLORRED;
DRAWFLAGTEXT(大陰燭,HIGH,'大陰燭,後市向淡,發生逆轉'),COLORCYAN;
DRAWFLAGTEXT(好友反攻,HIGH,'好友反攻,底部反轉'),COLORRED;
DRAWFLAGTEXT(光腳陰線,HIGH,'光腳陰線,下跌信號'),COLORCYAN;
DRAWFLAGTEXT(跳空缺口,HIGH,'注意向上還是向下跳空'),COLORblue;
DRAWFLAGTEXT(光頭陽線,HIGH,'光頭陽線,後市看漲'),COLORRED;
DRAWFLAGTEXT(三隻烏鴉,HIGH,'三隻烏鴉,可能見頂回落'),COLORCYAN;
DRAWFLAGTEXT(分離,HIGH,'分離,注意看漲分離和看跌分離'),COLORblue;
DRAWFLAGTEXT(長下影,HIGH,'長下影,持續下跌後出現,有可能止跌回升；在升勢末期出現,須多加留意'),COLORRED;
DRAWFLAGTEXT(長上影,HIGH,'長上影,表明行情上檔壓力沉重,升勢受阻'),COLORCYAN;
DRAWFLAGTEXT(下跌三部曲,HIGH,'下跌三部曲,下跌信號'),COLORRED;
DRAWFLAGTEXT(上升三部曲,HIGH,'上升三部曲,上漲信號'),COLORCYAN;
DRAWFLAGTEXT(早晨之星,HIGH,'早晨之星,見底回升'),COLORRED;
DRAWFLAGTEXT(黃昏之星,HIGH,'黃昏之星,見頂回落'),COLORCYAN;
DRAWFLAGTEXT(十字星,HIGH,'十字星,有轉向意味,注意股價位置在頂部還是底部'),COLORblue;
DRAWFLAGTEXT(長十字,HIGH,'長十字，注意在頂部還是底部'),COLORblue;
DRAWFLAGTEXT(垂死十字,HIGH,'垂死十字,下跌信號；'),COLORCYAN;
DRAWFLAGTEXT(早晨十字星,HIGH,'早晨十字星，上漲信號，見底回升'),COLORRED;
DRAWFLAGTEXT(黃昏十字星,HIGH,'黃昏十字星，下跌信號，見頂回落'),COLORCYAN;
DRAWFLAGTEXT(射擊之星,HIGH,'射擊之星,可能見頂回落,可靠性低'),COLORCYAN;
DRAWFLAGTEXT(倒轉錘頭,HIGH,'倒轉錘頭,可能見底回升'),COLORRED;
DRAWFLAGTEXT(錘頭,HIGH,'錘頭,可能見底回升,如有量配合,信號強烈'),COLORRED;
DRAWFLAGTEXT(吊頸,HIGH,'吊頸,上升行情中見頂回落,頂部出現,見頂信號'),COLORCYAN;
DRAWFLAGTEXT(平頂,HIGH,'平頂,溫和的反轉'),COLORCYAN;
DRAWFLAGTEXT(穿頭破腳,HIGH,'穿頭破腳,頂部出現,見頂回落信號'),COLORCYAN;
DRAWFLAGTEXT(烏雲蓋頂,HIGH,'烏雲蓋頂,見頂回落信號'),COLORCYAN;
DRAWFLAGTEXT(曙光初現,HIGH,'曙光初現,後市見底回升'),COLORRED;
DRAWFLAGTEXT(身懷六甲,HIGH,'身懷六甲,出現在底部,是見底回升信號；出現在頂部,是見頂回落信號'),COLORRED;
DRAWFLAGTEXT(十字胎,HIGH,'十字胎'),COLORRED;
DRAWFLAGTEXT(平底,HIGH,'平底,溫和的反轉'),COLORRED;
DRAWFLAGTEXT(大陽燭,HIGH,'大陽燭,,看漲'),COLORRED;
DRAWFLAGTEXT(三個白武士,HIGH,'三個白武士,每日收盤價上移,表示可能見底回升'),COLORRED;
DRAWFLAGTEXT(雙飛烏鴉,HIGH,'雙飛烏鴉,行情將見頂回落'),COLORCYAN;
DRAWFLAGTEXT(孕育線,HIGH,'孕育線,注意股價位置'),COLORblue;
DRAWFLAGTEXT(多方炮,HIGH,'多方炮，在底部出現有上漲以為，在中間出現有可能是上漲中繼，頂部出現是復合見頂信號 '),COLORRED;
DRAWFLAGTEXT(出水芙蓉>0,HIGH,'陽線穿過20、40、60日季均線，上攻勢頭初現!'),COLORRED;
4. 大智慧DDZ指標如何使用
DDZ（大單差分 指標）：
紅色綵帶表示了大資金買入強度，色帶越寬、越高表示買入強度越大。當綵帶突然升高放寬時往往預示短線將快速上漲。 對大單質量的評價，反映大資金的實力，我們稱之為DDZ。DDZ的作用在於衡量買賣雙方大單的力度，對於大盤股和機構分歧較大的股票比較有效，當然對於多方主力占絕對優勢的股票更容易排行靠前.在動態顯示牌下對該指標排序可以選出短線強勢股.
所謂DDX翻紅，是指DDX指標中DDX的值大於0，直觀視覺上表現為：指標內的柱型顯示為紅色，DDX後面的尖頭向上「↑」紅色！這就叫DDX翻紅.有了DDE後，就可以將投資股票的過程反過來，先使用DDE去選擇走勢好的股票，然後在對這些股票進行基本面分析，來進行投資決策。另外要強調一點，DDX和DDY是追強勢股的指標，不能用做抄底等操作.DDX更像是一個強度的指標，能夠體現出股票目前的走勢強弱，其參考的時間價值相對較短，2-3天內會比較有效.DDY更多體現的是主力操作方向，能夠體現出主力的操作方向。其參考的時間價值相對長一些。特別是DDY曲線持續向上的股票，體現出主力在持續增倉。
5. 大智慧軟體有哪個指標可以顯示今天收盤後K線有跳空缺口(高開收陽線)的股票
公式入門
我們大多數的用戶並不是完全了解「公式編輯器」的意義，簡單地，我們可以從以下幾個角度進行理解：
一、指標分析：
「公式編輯器」好比是一個工作母床，通過這個工作母床可以製造出所需要的各式各樣的零件，同樣，在指標分析的工作中，利用編輯器可以編寫出相應的分析
條件，這種方法是在技術分析當中最為常用的方法之一。例如，指標KD、指標MA等等，通過對這些指標的觀察、分析，找出一些合適的條件作為買入賣出點。當
然，我們也許需要的是一些自己的指標，一些自己的准確的指標，更多的MB、MC、MD等等，這一切我們通過「公式編輯器」可以實現。
二、條件選股：
編寫公式都要用到什麼東西？
我們留下了許多問題--都是公式編寫的基礎問題，所以我們這節課來解決這些基礎的問題。
什麼是技術指標？
MA均線就是一種技術指標，我們在炒股的時候，經常會將一些行情數據進行數學計算得出一些曲線等等，方便我們掌握股市的變動情況。
什麼是條件選股？
簡單講，就是按照您的設定的條件用電腦幫助您完成一些太多太復雜的挑選--比如您有一些好的心得和方法，可使有1000多隻股票，您就是有100雙眼睛有時也不
一定可以看得過來，這時電腦就派上用場了！
什麼是參數？
比如講：10日均線，您可以把10日當作參數，好處在於，您覺得需要修改成5日的時候，就可以使用一些簡單的方法，例如參數精靈來很方便的修改和調整。參數
需要名字，例如M就不錯。還要規定參數的范圍，例如1日至260日。這樣我們就可以在1到260之間任意調節M的值了，M最常用的數填在「預設」一欄，例如你最喜
歡用10日均線，那就填10吧。
什麼是周期？
這么解釋吧！我們有的投資者喜歡使用日線圖作技術分析；有的喜歡用5分鍾的K線；有的喜歡使用長一點時間的，例如周線。所以在公式設計中，允許不同喜好
的使用者選擇不同的分析時間--就是可以選擇不同的周期。
什麼是函數？
函數在公式編寫非常重要，如果作個比喻，我們用一種語言去告訴電腦我的想法，並且讓它去幫我做，那麼函數就是這種語言的單詞。
我們在公式編輯器中選擇插入函數，就可以看到裡面有許多的函數，我們在附錄中有一個簡表，大家可以到那裡去檢索！
例一：
一根K線有四個價格組成：
最高價：HIGH
收盤價：CLOSE
最低價：LOW
開盤價：OPEN
成交量：VOL
成交額：AMO
例二：
兩條均線不斷地交叉，就專門設定了一條函數來描述兩條線交叉：CROSS（X，Y）
假如下圖中的兩條均線一條名叫X，另外一條叫Y
CROSS（X，Y）表示X向上穿過了Y
CROSS（Y，X）表示Y向上穿過了X
例三：
前面的CLOSE，還是VOL，都表示當天，或者您使用的不是日線，那就表示本周期的數據，那麼前幾天的怎麼表示呢？
REF（X，M）
例如：
REF（Close，5）表示5天前的收盤；
REF（Vol，10）表示10天前的成交量；
這里的M就是參數，您現在明白了什麼是參數了嗎？
例四：
如果我想把兩個條件並列在一起怎麼辦？
AND
X AND Y就表示條件X和條件Y
好了！本課結束吧--有點稍慢，下面會好一些！
編寫一條最簡單的指標線
通過前幾課的學習，我們今天開始使用軟體的公式編輯功能編寫我們自己的第一條指標線。
其實不難，你應該對自己有信心！
按照主菜單-工具-公式**-選擇-「技術指標」-點擊「新建」，然後在公式編輯器中留下你的第一行腳印吧！
點擊：「確認」，現在看一下我們第一條指標線。
這條指標線與你的想法相符嗎？
總結與補充：
1、如果選擇：「主圖疊加」，我們的指標線會與K線圖顯示在同一個圖形框中，現在我們的指標線顯示在其下方，即「副圖」中；
2、參數可以有，也可以沒有，但是鼓勵大家設置參數，這是非常好的習慣；
3、一個句子完了，別忘了以分號結尾；
你的公式寫得對不對，可以通過「測試公式」來檢查，如果錯了，它會告訴你錯在哪裡。
編寫最常用的均量和均價線
均價線，不就是那個「移動平均線MA」什麼的嗎？不過，話說回來，聽說10個人裡面有11個人都在使用，我可得學習學習！
原理是？？
5日平均線=（今天收盤價+昨天收盤價+.....--5天前的收盤價）/5；
10日平均線=（今天收盤價+昨天收盤價+......+10天前的收盤價）/10；
150日平均線=（今天收盤價+昨天收盤價+......+150天前的收盤價）/150；
200日平均線......不是這么麻煩吧？難道我每天都要寫這么多得數才得到一條平均線？？？？
你有什麼辦法？
MA1=MA（CLOSE，5）；
MA2=MA（CLOSE，10）；
MA3=MA（CLOSE，50）；
......
當然是有簡單的方法了！你把我在上面說過的話寫下來，按照前面幾課講的，寫在公式的編輯欄當中就可以了！
注意：
「MA」表示的就是計算平均值。
在括弧內寫上計算的對象和計算的時間長度。
MA1，MA2，MA3......是好幾條指標線，別忘記了用分號把它們分開。
最後呢？電腦自己會把它們一起畫出來。
均量線？？？
均價線都有了，照著葫蘆畫瓢，把收盤價CLOSE換成成交量VOL就行了！
MA1：MA（VOL，5）；
MA2：MA（VOL，10）；
MA3：MA（VOL，150）；
MA4：MA（VOL，200）；
今天有幾只發生MA金叉？
我們學習了編寫MA移動平均線，關於這幾條指標線如何使用？我想大家可能都比我清楚。例如短期均線和長期均線發生了金叉或者死叉，......等等，葛蘭維爾
的八項法則......如果說如何用分析家軟體編寫一個條件，讓電腦把今天兩個市場的股票中所有發生了黃金交叉的股票選出來呢？
想知道嗎？這就是「條件選股」，按照「條件」電腦自動「選擇股票」出來，可以供您分析，要不然的話，技術分析的投資者都會累死了！
跟我學！
第一步：「工具」欄中選中「公式**器」
第二步：我們現在選擇「新建」一個「條件選股」公式，結果出現了下面的編輯欄！然後在裡面寫上您的條件！
第三步：按照說明書上的步驟選股就行了！
注意：
1、在條件選股中點擊「新建」；
2、原來MA5：MA（CLOSE，5）；
表示的是一條指標線，可是現在我們在條件選股當中只要引用它，不需要把它畫出來。所以我們在冒號的後面加一個符號，表示等會要引用它：MA5：=MA（CLOSE
，5）；
這個在分析家的公式編輯中，叫做「中間表達式」。
X=1；
Y=X+1；
Y=？
我們學過上面的數學，都知道把X=1代入到Y的計算中去，「X=1；」就是一個中間表達式，您明白了嗎？
條件選股總結：
1、指標和條件選股在結構上沒有差別，只是在內容上，條件選股要多加上我們的條件，比如大於10，或者交叉等等！
2、中間表達式可以幫助我們清晰的表達我們的公式，不至於使公式的結構特別的混亂！
如何編寫BIAS指標？
如果大家都是均線的忠實愛好者的話，那麼大家一定牢牢記得在均線大師哥南威爾的8***則當中的第四條和第五條中曾經提到了當股價偏離均線太遠的時候，便
會向它靠攏，但是並不提到多遠才會靠攏--為了解決這個問題，也為了我們更好地用客觀數據來體現股價運動的過程，乖離率這個指標應運而生。
本課我們的任務就是通過對乖離率的原理到編寫方法的學習來加強我們對公式設計的理解。
首先，什麼是乖離率？
以當日的均線價格為准，股價和均價之間的差距稱為乖離程度，以乖離程度除以均價的百分比就是乖離率。
當日股價與10日均線的乖離率=（當日股價-10日均價）/10日均價*100；
當日股價與20日均線的乖離率=（當日股價-20日均價）/20日均價*100；
當日股價與30日均線的乖離率=（當日股價-30日均價）/30日均價*100；
原理就是這么簡單，可是怎麼使用呢？您別急，所用的指標其實都是在觀察當中得出一定的啟示，您先實現這幾條指標線，讓它們以圖形的方式出現在您的面前
，然後您再去觀察，一定會事半功倍！
比如編寫10日乖離率
第一步：乖離率的命名，崇尚人家的習慣，依舊使用BIAS，那麼第一條就叫做BIAS1好了！
第二步：當日股價用CLOSE表示；
10均價我們在前一節課剛剛學過，順手拈來，用MA（CLOSE，10）表示；
第三步：一樣使用加減乘除符號以及括弧，只是要注意只有小括弧，沒有中大括弧，那麼公式就有了--
BIAS1：（CLOSE-MA（CLOSE，10））/MA（CLOSE，10）*100；
這樣的話我們在技術指標編輯器中將另外兩條指標也同樣寫下來，就得到了BIAS指標，請看下圖：
第四步：就是您得自己好好觀察您的指標公式在各個股票的表現，得出您自己的結論，因為每一個投資者即使是在使用同樣一個指標的時候，都會有不同的理解
，我們無法判斷優劣，但是有一條可以告訴我們答案，那就是永遠讓市場說話，因為它永遠是對的！
如果您不介意的話，可以參考BIAS，不過僅供參考！
您明白怎麼編寫了嗎？
====================================================================================
我能不能直接用寫好的指標公式？
我想用KD指標選股，能不能直接寫成「D＞20」就可以執行了？
當然可以！考慮到了這種偷懶的做法，所以我們一共提供了兩種供偷懶的人士使用，其中一種與上面的要求只是在寫法上稍有不同！
第一個方法：
第一步：在條件選股的編輯器中點擊「引入指標公式」。
引入「其他公式」。然後，我們從中選擇一個，例如「KD」，讓我們來看一下結果如何？
第二步：上一步的操作結果請看右邊的圖形，系統自動的把KD指標的整個編寫內容搬來了！
現在需要我們做的就是：續上一行條件「D＜20」，OK！完成！
有沒有簡單的方法？
第二個方法：就一句話：「KDJ，D」＜20；
「KDJ，D」
表示現在我要是用KDJ指標當中的D指標，不過大家要看清楚是怎麼寫的哦！寫錯了計算機可是不會改錯的！
總結：
用上面的方法可以引用所有指標，所以不必寫那麼多！
注意格式上，兩邊用引號括起來，指標名稱KDJ和指標線名稱D之間用「，」隔開！
額外加餐
現在我們可以很方便的做另外一件事了，我們可以將通常說的KDJ買入條件完整的表達出來了：
「KD指標發生了黃金交叉，並且D＜20」
T1：=「KDJ，K」；--引用K線；
T2：=「KDJ，D」；--引用D線；
條件： AND在分析家中就表示「並且」，將兩個條件並列起來
CROSS（T1，T2）ANDT2＜20；
第九課 放量、縮量、上漲、下跌、收陽、收陰
在前面的學習當中，我們見到了一些基本的表達方法、方式，今天我們的任務是學習一些常見的概念如何編寫，例如上面所列出來的放量、上漲等等，因為這些
都是在公式編寫過程當中要用到的基本的小的形態特徵，許多的技術指標的選股條件都是由它們組成的。
放量：
1、今日比昨日的成交量放大了1倍：
VOL/REF（VOL，1）＞2；
2、今日的五日均量比前五天的五日均量放大了3倍：
AA：=MA（VOL，5）；
BB：=REF（AA，5）；
AA/BB＞4；
3、今天的成交量達到了整個流通盤的10%以上：
VOL/CAPITAL＞10/100；
（注意，10%的表達式是10/100，或者0.1）
縮量：
1、今日比昨日的成交量縮小了1倍：
VOL/REF（VOL，1）＜0.5；
2、今日的五日均量比前五天的五日均量縮小了一半：
AA：=MA（VOL，1）＜0.5；
BB：=REF（AA，5）；
AA/BB＜0.5；
3、今天的成交量不足整個流通盤的0.5%：
VOL/CAPITAL＜0.5/100；
上漲：
1、今日漲幅達到了7%以上：
CLOSE/REF（CLOSE，1）＞1.07；
2、十日均價繼續上漲：
AA：=MA（CLOSE，10）；
BB：=REE（AA，1）；
AA＞BB；
下跌：
同上面的表達方式一樣，將方向改變了而已：
收陽、收陰：
1、當天收陽：CLOSE＞OPEN；
2、當天收陰：CLOSE＜OPEN；
高開、低開：
1、當天股價高開，言下之意開盤高於昨日收盤：OPEN＞REF（CLOSE，1）；
2、當天股價低開：OPEN＜REF（CLOSE，1）；
跳空：
跳空亦有向上和向下兩種：
當日開盤在昨日最高之上，即為向上跳空：OPEN＞REF（HIGH，1）；
反之，開盤小於昨日的最高價，為向下跳空：POEN＜REF（LOW，1）；
事實上，我們在編公式的過程，就是將這些條件有機地結合起來作為我們判斷的條件。舉一個很簡單的例子，如果是K線形態呈現出放量上攻的態勢，那麼如何編
寫這個公式呢？高開高走又應該如何編寫呢？
我們把放量和上漲的兩個條件組合在一起，讓某一天的形態特徵同時滿足兩個條件就達到目的；同樣地將高開的高走兩個條件結合在一起，也就找到了我們所需
的條件。
結果就是：
放量上攻之一，以上面所舉例組合：
AA：=VOL/REF（VOL，1）＞2；
BB：=CLOSE/REF（CLOSE，1）＞1.07；
AA AND BB；
高開高走：
AA：=OPEN＞REF（CLOSE，1）；
BB：=CLOSE＞OPEN；
AA AND BB；
OK！本課到此結束，留下一個問題，看看您有沒有真正的理解，向上跳空之後兩天內並未回補如何編寫呢？
提示：實際上就是昨天發生了跳空缺口，這兩天的最低價一直在兩天前的最高價之上。
AA：=REF（OPEN，1）＞REF（HIGH，2）；
BB：=REF（LOW，1）＞REF（HIGH，2）；
CC：=LOW＞REF（HIGH，2）；
AA AND BB AND CC；
仔細一想，若BB成立，AA一定成立，AA實際上沒有存在的必要，你想通了嗎？
更簡單的方法，下面的一句話可以的上面的四句：
COUNT（LOW＞REF（HIGH，2），2）=2；
第十課 漲停板攻擊？
學了這么多了，應該教點實戰的內容了！我們來學習一下別人的經驗，「漲停板追擊」，同時這裡面還潤孕育著一個簡單但是又頗有意義的道理！
一、量化的概念
我們都知道，按規定漲幅不得超過10%，但是由於四捨五入的關系，常常有9.98%、10.23%等等的漲停板，所以我們要找一個合適的數值，然後用分析家的語言告
訴計算機，這個過程學名叫量化！
比如我們考察之後，決定讓大於9.99%的都為漲停。
二、編寫公式
其實就一句話：今日收盤除以昨日收盤的值大於1.0999
X：=CLOSE/REF（CLOSE，1）＞1.0999；
三、測試我們的條件
大家都知測試的功能，要不然你怎麼知道你的經驗在歷史上的表現是好還是不好呢？
按照下圖指引進入條件選股的界面，之後選中您的條件，具體辦法請參見（使用說明書）。然後填入測試時間和測試標准！
在這里我們的測試方法是：
測試時間是從2000/01/01到2001/03/02，測試股票共計583隻，初始投入100，000元。
當滿足買入公式中定義的條件時，也就是漲停板時，按照收盤價使用相同資金買入一隻股票，當滿足以下平倉條件時按照收盤價平倉；買入5日後強制平倉或者虧
損達到3%止損平倉或者利潤達到5%止贏平倉，然後按照以上的規則統計在測試的時間段內的所有交易的狀況。
這是一種追漲的短線方法，所以測試的時間我們只用5天，目標利潤為5%，（非常抱歉，因為其中的設置和選擇方法十分靈活而且需要較好的理解能力，所以我們
在這里就不介紹具體的內容了）
點擊開始測試！一切OK！來看結果吧！
1、從成功率上看，實際達到5%的獲利要求的交易次數67.89%，我們已經比較滿意這個結果了，可是要用於實戰，可不可以再提高呢？
2、所謂的提高就是優化的一個內容，簡單說，優化就是讓它更好！優化我們的條件，讓它的表現更好！
3、加上一個縮量的條件，比如當日成交量小於5日的均量；Y：=VOL＜MA（VOL，5）；大家可以做一下測試，看看結果如何！以下是同樣測試條件下的結果。 X
AND Y；
您滿意嗎？我們的成功率已達到了80%，剩下的任務就是您如何操作的問題了！
註：請大家考慮一下在實戰當中，如果您按此買入可不可行？
總結：編寫公式並不是為了編公式而編寫復雜的公式，您個人對某一個特徵或者形態的理解最重要。所以光有經驗不夠，您還得把它轉化成您自己的應對策略！
您需要不斷總結、測試、優化您的公式。
第十一課 多頭排列--良好的上升趨勢
均線的多頭排列一直以來都被大家視為一種良好的上升趨勢的表現，因為這種形態的形成需要較長的時間，和較大的能量，而被主力或者莊家利用作為騙線的可
能性就比較小，股市當中也遵循慣性的原理，當一個趨勢形成之後，要改變它，是不容易的，因為股價有著沿著原來的運動方向上的慣性！
首先，讓我們來看看幾種多頭排列：
5、10、30日均線：5、10、30日均線：30、60、90日均線：
在圖一中和圖二中我們採用的是同一周期的均線，即都是5、10、30日均線，我們可以觀察到在同一周期下的均線排列有相同之處，也有很大不同之處：圖一中的
5日均線=10日均線、30日均線平滑優美，而在圖二中的5日和10日均線不斷的碰及30日均線然後上升；
在圖三中我們選用的是30、60、90日均線，相對來說均線的多頭排列也顯得很平滑。
為什麼會有這樣的差別呢？如果您要是認真一點的話，就可以發現原來前兩圖的K線走得不一樣，一個一波拉到頭，一個分成幾波拉到頭，而在圖三當中我們採用
了較長周期的均線系統，從而在一定程度上過濾了這種現象，具體在使用的過程中，您可要多注意它們的區別！
好了，我們來看一下如何編寫，拿第一個為例，觀察它們的特徵：
5/10/30日均線依次從上而下的排列，這種情況維持一段時間，假設我們這里定為4天以上：
5/10/30日均線依次從上而下的排列：
AA：=MA（CLOSE，5）；
BB：=MA（CLOSE，10）；
CC：=MA（CLOSE，30）；
T1：=AA＞BB AND BB＞CC；
以上情況維持一段時間，假設我們這里定為4天以上：
COUNT（T1，4）=4；
COUNT（X，N）表示統計在N天內滿足條件X的有幾天。
最終的結果就是如下所示：
AA：=MA（CLOSE，5）；
BB：=MA（CLOSE，10）；
CC：=MA（CLOSE，30）；
T1：=AA＞BB AND BB＞CC;
COUNT（T1，4 ）=4
編寫完畢，我們在上面的例子當中，舉的是最簡單的一個，其實您在編寫的過程當中，還可以加上一些比較准確地描述，以取得更好的效果，例如同時三條均線
向上發散等，當然還有您自己的心得。
=================================================================
第十二課 逃頂K線形態之--黃昏之星
一、概念學習
當市場出現一條大陽線後，通常會產生跳空高開的情況，有時便會出現十字星或類似十字星的小陰線（小陽線）。另一種相反的情況是出現在一條大陰線後，在
這兩種情況下形成的類似十字星的K線都被稱為「星型線」。
當該形態出現在一段上升行情的當中，就很容易形成所謂的經典K線形態--黃昏之星。
二、編制過程
通過我們前面的學習，其實已經可以比較輕松的編制這個條件了--前人已經清晰地把這個形態的具體特徵描述出來，剩下的工作就是把這些特徵用數字表示--這
就是前面提到的量化的過程！
該圖組合一共由三根K線合成，我們按照以下的步驟一步一步地一邊尋找每日K線的特徵，一邊進行編寫：
為了結構簡單起見，首先將二天的高開低收用中間表達式表達出來，因為我們在後面的編寫過程中會分別使用到這些數據。
1、今日K線的：開-a1, a1：=open；
收-a2， a2：=close；
高-a3, a3：=high；
2、昨天K線的：開-b1, b1：=ref(open，1)；
收-b2， b2：=ref(close，1)；
高-b3， b3：=ref(high，1)；
低-b4， b4：=ref(low，1)；
3、前天K線的：開-c1, c1：=ref(open，2)；
收-c2, c2：=ref(close，2)；
高-c3, c3：=ref(high，2)；
低-c4, c4：=ref(low，2)；
4、我們將會分別描述出三天的K線形態，然後匯總，首先我們觀察今日K線的特徵，今天是一根低開低走的大陰線，我們給它一些數字上的定義：
a、今日開盤價小於昨日收盤價； aa:=a1＜b2 and
b、今日的陰線實體較長，我們用開盤價和收盤價相比，長度大於4%：a1/a2＞1.04；
5、昨日K線的特徵，是一根十字形態的K線，並且在左右兩根K線之上，分別表達為：
a、昨日跳開，高於前天的收盤： bb：=b1＞c3
b、昨日收盤同樣在缺口之上： and b2＞c3
c、線形實體長度很小，也就是昨日開盤和收盤之差比昨日開盤的值小於0.01：and abs(b1-b2)/b1＜0.01
d、K線有上下影線，可以表示為最高價和最低價不等於收盤價也不等於開盤價：and b3＞b1 and b3＞b2 and b4＜b1 and b4＜b2
e、當日的最高價為20天以來的最高價： and b3=hhv(high，20)；
6、前日K線的特徵：股價大幅上揚，幅度較前一日收盤高出4%並且收盤大於開盤：cc:=c2/ref(close，3)＞1.04 and c2＞c1；
綜合選股條件：最後我們將三天的K線特徵會合起來，合成一個最後的條件就是由圖所示內容： aa and bb and cc
6. （有關炒股軟體的）大智慧新一代炒股軟體有沒有什麼技術指標提示分析圖中的最新缺口呢
編一個公式
---------------------
高開開盤價缺口:O>REF(C,1),LINETHICK0,COLOR0000EE;
高開最低價缺口:L>REF(C,1),LINETHICK0,COLORFF00FF;
低開開盤價缺口:O<REF(C,1),LINETHICK0,COLORAAAAAA;
低開最高價缺口:H<REF(C,1),LINETHICK0,COLOREEEEEE;
STICKLINE(高開開盤價缺口,O,REF(C,1),6,0),COLOR0000AA;
STICKLINE(高開最低價缺口,L,REF(C,1), 8,0),COLORFF00FF;
STICKLINE(低開開盤價缺口,O,REF(C,1), 6,0),COLORAAAAAA;
STICKLINE(低開最高價缺口,H,REF(C,1), 8,0),COLOREEEEEE;
{K線}
STICKLINE(C>=O,C,O,3,0),COLORRED;
STICKLINE(C>=O,H,MAX(O,C),0.1,0),COLORRED;
STICKLINE(C>=O,MIN(O,C),L,0.1,0),COLORRED;
STICKLINE(C<=O,C,O,3,0),COLORCYAN;
STICKLINE(C<=O,H,MAX(O,C),0.1,0),COLORCYAN;
STICKLINE(C<=O,MIN(O,C),L,0.1,0),COLORCYAN;
7. 求高手編輯一個大智慧跳空低開長下影選股指標公式，萬分感謝。
你沒有指定低開的量，下影線要求多少也沒說明，我寫一個給你，你看看：
C/REF(C,1)<1.02 AND MIN(C,O)/L>1.02;
說明：2%低開以上，下影線2%以上
8. 大智慧的指標圖怎麼看
分時圖的基礎知識
分時圖是指大盤和個股的動態實時（即時）分時走勢圖，其在實戰研判中的地位極其重要，是即時把握多空力量轉化即市場變化直接的根本所在，在這里先給大家介紹一下概念性的基礎知識。
大盤指數即時分時走勢圖
1）白色曲線：表示大盤加權指數，即證交所每日公布媒體常說的大盤實際指數。
2）黃色曲線：大盤不含加權的指標，即不考慮股票盤子的大小，而將所有股票對指數影響看作相同而計算出來的大盤指數。
參考白黃二曲線的相互位置可知：A）當大盤指數上漲時，黃線在白線之上，表示流通盤較小的股票漲幅較大；反之，黃線在白線之下，說明盤小的股票漲幅落後大盤股。B）當大盤指數下跌時，黃線在白線之上，表示流通盤較小的股票跌幅小於盤大的股票；反之，盤小的股票跌幅大於盤大的股票。
3）紅綠柱線：在黃白兩條曲線附近有紅綠柱狀線，是反映大盤即時所有股票的買盤與賣盤在數量上的比率。紅柱線的增長減短表示上漲買盤力量的增減；綠柱線的增長縮短表示下跌賣盤力度的強弱。
4）黃色柱線：在紅白曲線圖下方，用來表示每一分鍾的成交量，單位是手（每手等於100股）。
5）委買委賣手數：代表即時所有股票買入委託下三檔和賣出上三檔手數相加的總和。
6）委比數值：是委買委賣手數之差與之和的比值。當委比數值為正值大的時候，表示買方力量較強股指上漲的機率大；當委比數值為負值的時候，表示賣方的力量較強股指下跌的機率大。
個股即時分時走勢圖
1）白色曲線：表示該種股票即時實時成交的價格。
2）黃色曲線：表示該種股票即時成交的平均價格，即當天成交總金額除以成交總股數。
3）黃色柱線：在紅白曲線圖下方，用來表示每一分鍾的成交量。
4）成交明細：在盤面的右下方為成交明細顯示，顯示動態每筆成交的價格和手數。
5）外盤內盤：外盤又稱主動性買盤，即成交價在賣出掛單價的累積成交量；內盤又稱主動性賣盤，即成交價在買入掛單價的累積成交量。外盤反映買方的意願，內盤反映賣方的意願。
6）量比：是指當天成交總手數與近期成交手數平均的比值，具體公式為：現在總手/（（5日平均總手/240）*開盤多少分鍾）。量比數值的大小表示近期此時成交量的增減，大於1表示此時刻成交總手數已經放大，小於1表示表示此時刻成交總手數萎縮。
實戰中的K線分析，必須與即時分時圖分析相結合，才能真實可靠的讀懂市場的語言，洞悉盤面股價變化的奧妙。K線形態分析中的形態頸線圖形，以及波浪角度動量等分析的方法原則，也同樣適合即時動態分時走勢圖分析，具體實戰研判技巧筆者將另文探討。
怎樣運用分時圖來研判大盤
大盤全天的走勢往往瞬息多變，有時上午走的很強勁，下午可以突然跳水。而有時上午跌的很厲害，下午卻可以力挽狂瀾。所以如能事先判斷當日大盤是收陰還是收陽？對於有些股民做T+0或是當日的短線買股至關重要。下面就是一種准確率較高的一種判斷方法：
A當股指挑空高開
1）股指跳空高開後半個小時內，一直運行在缺口上方強勢上揚，如出現此種情況，當日大盤判斷收為陽線，可以在盤中回調時吸納。
2）股指跳空高開後半個小時內，股指先跌補完缺口後再上揚，在10點時股指處於上漲狀態的話，也應判斷當日大盤收陽，但准確的幾率沒有第一種高。
3）股指跳空高開後半個小時內，股指一路下跌，在10點時股指處於下跌狀態，則應判斷當日收陰，當日因小心操作。
B當股指平開
1）股指開盤半個小時內，股指一路強勢上揚，則當日收陽。
2）股指開盤半個小時內，股指一路下跌，則當日收陰。
3）股指開盤半個小時內，股指如先跌後漲，10點時如股指出於上漲狀態，則判斷當日收陽。
4）股指開盤半個小時內，股指如先漲後跌，10點時如股指處於下跌狀態，則判斷當日收陰。
C當股指底開
1）當股指底開後半個小時內如一路下跌，則判斷當日大盤收陰，此種准確率較高，且當日容易大跌。
2）當股指底開後半個小時內馬上補缺口一路上揚，則當日收陽的幾率很高。
3）當股指底開後半個小時內先反彈，但缺口沒有補完，在10點左右又下跌，則當日收陰。
4）當股指底開後半個小時內補完缺口再下行，則還是以判斷收陰。
以上的情況都屬於預測，所以只是准確概率的高低，並不是說一定對，下面我們再講講兩中特殊的情況；
一、有時早上開盤後半個小時內，股指波動的幅度非常小，往往在一二個點之內，且紅柱和綠柱都非常短，有是相互交錯，如出現這種情況，則當日大盤容易出現大漲大跌的走勢。一般以大漲居多。
二、有時早盤開盤後半個小時內，股指波動幅度非常大，呈上竄下跳的走勢，則可以判斷為當日大盤圍繞開盤指數大副震盪。
9. （關於大智慧）有那些技術指標如何看
其實大智慧軟體是帶有指標解釋的.
以普通版的大智慧5.55版本為例.在K線狀態下,點擊頂行的<分析>--<指標屬性>---<指標注釋>即可.
而最新版的高速行情系統.則應點擊頂行的<幫助>--<技術指標參考>.
不過,人是活的,指標是死的.還是不要沉迷於技術分析的好.